valaccodecompiler.vala 2.68 KB
Newer Older
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83
/* valaccodecompiler.vala
 *
 * Copyright (C) 2007  Jürg Billeter
 *
 * This library is free software; you can redistribute it and/or
 * modify it under the terms of the GNU Lesser General Public
 * License as published by the Free Software Foundation; either
 * version 2 of the License, or (at your option) any later version.

 * This library is distributed in the hope that it will be useful,
 * but WITHOUT ANY WARRANTY; without even the implied warranty of
 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
 * Lesser General Public License for more details.

 * You should have received a copy of the GNU Lesser General Public
 * License along with this library; if not, write to the Free Software
 * Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301  USA
 *
 * Author:
 * 	Jürg Billeter <j@bitron.ch>
 */

using GLib;

/**
 * Interface to the C compiler.
 */
public class Vala.CCodeCompiler {
	public CCodeCompiler () {
	}

	/**
	 * Compile generated C code to object code and optionally link object
	 * files.
	 *
	 * @param context a code context
	 */
	public void compile (CodeContext! context) {
		string pc = "pkg-config --cflags";
		if (!context.compile_only) {
			pc += " --libs";
		}
		foreach (string pkg in context.get_packages ()) {
			pc += " " + pkg;
		}
		string pkgflags;
		int exit_status;
		Error err = null;
		if (!Process.spawn_command_line_sync (pc, out pkgflags, null, ref exit_status, out err)) {
			Report.error (null, err.message);
			return;
		} else if (exit_status != 0) {
			Report.error (null, "pkg-config exited with status %d".printf (exit_status));
			return;
		}

		// TODO compile the C code files in parallel

		string cmdline = "cc";
		if (context.debug) {
			cmdline += " -g";
		}
		cmdline += " -O%d".printf (context.optlevel);
		if (context.compile_only) {
			cmdline += " -c";
		} else if (context.output != null) {
			cmdline += " -o " + Shell.quote (context.output);
		}
		cmdline += " " + pkgflags;

		/* we're only interested in non-pkg source files */
		var source_files = context.get_source_files ();
		foreach (SourceFile file in source_files) {
			if (!file.pkg) {
				cmdline += " " + Shell.quote (file.get_csource_filename ());
			}
		}

		bool success = Process.spawn_command_line_sync (cmdline, null, null, ref exit_status, out err);

		/* remove generated C source and header files */
		foreach (SourceFile file in source_files) {
			if (!file.pkg) {
84 85
				FileUtils.unlink (file.get_csource_filename ());
				FileUtils.unlink (file.get_cheader_filename ());
86 87 88 89 90 91 92 93 94 95
			}
		}

		if (!success) {
			Report.error (null, err.message);
		} else if (exit_status != 0) {
			Report.error (null, "cc exited with status %d".printf (exit_status));
		}
	}
}