dnl Process this file with autoconf to produce a configure script.

AC_PREREQ(2.52)

AC_INIT(gthumb, 2.11.0, http://bugzilla.gnome.org/enter_bug.cgi?product=gthumb)
AC_CONFIG_SRCDIR(src/main.c)
AM_INIT_AUTOMAKE(AC_PACKAGE_NAME, AC_PACKAGE_VERSION)

AM_CONFIG_HEADER(config.h)

AM_PROG_LIBTOOL
AM_PROG_LEX
AC_PROG_YACC

AC_CONFIG_MACRO_DIR([m4])
GNOME_DOC_INIT

dnl ==========================================================================
dnl
dnl If you add a version number here, you *must* add an AC_SUBST line for
dnl it too, or it will never make it into the spec file!
dnl
dnl ==========================================================================

GLIB_REQUIRED=2.19.0
GTK_REQUIRED=2.16.0
LIBXML_REQUIRED=2.4.0
LIBGNOME_REQUIRED=2.6.0
LIBGNOMEUI_REQUIRED=2.6.0
GNOME_DESKTOP_REQUIRED=2.25.1
LIBGNOMECANVAS_REQUIRED=2.6.0
GIO_REQUIRED=2.16.1
GNOME_VFS_REQUIRED=2.6.0
LIBGLADE_REQUIRED=2.4.0
BONOBO_REQUIRED=2.6.0
LIBOPENRAW_REQUIRED=0.0.4
EXIV2_REQUIRED=0.18
GSTREAMER_REQUIRED=0.10.15

AC_SUBST(GLIB_REQUIRED)
AC_SUBST(GTK_REQUIRED)
AC_SUBST(LIBXML_REQUIRED)
AC_SUBST(LIBGNOME_REQUIRED)
AC_SUBST(LIBGNOMEUI_REQUIRED)
AC_SUBST(LIBGNOMECANVAS_REQUIRED)
AC_SUBST(GIO_REQUIRED)
AC_SUBST(GNOME_VFS_REQUIRED)
AC_SUBST(LIBGLADE_REQUIRED)
AC_SUBST(BONOBO_REQUIRED)
AC_SUBST(LIBOPENRAW_REQUIRED)
AC_SUBST(EXIV2_REQUIRED)
AC_SUBST(GSTREAMER_REQUIRED)

AM_PATH_ORBIT2

dnl ===========================================================================

PKG_CHECK_MODULES(GTHUMB,				\
	glib-2.0 >= $GLIB_REQUIRED			\
	gthread-2.0					\
	gmodule-2.0					\
	gtk+-2.0 >= $GTK_REQUIRED			\
	libgnome-2.0 >= $LIBGNOME_REQUIRED		\
	libgnomeui-2.0 >= $LIBGNOMEUI_REQUIRED		\
	gnome-desktop-2.0 >= $GNOME_DESKTOP_REQUIRED	\
	libgnomecanvas-2.0 >= $LIBGNOMECANVAS_REQUIRED	\
	libbonobo-2.0 >= $BONOBO_REQUIRED		\
	libbonoboui-2.0 >= $BONOBO_REQUIRED		\
	bonobo-activation-2.0 >= $BONOBO_REQUIRED	\
	gio-2.0 >= $GIO_REQUIRED			\
	gnome-vfs-2.0 >= $GNOME_VFS_REQUIRED		\
	gnome-vfs-module-2.0				\
	exiv2 >= $EXIV2_REQUIRED			\
	libxml-2.0 >= $LIBXML_REQUIRED			\
	libglade-2.0 >= $LIBGLADE_REQUIRED)
AC_SUBST(GTHUMB_LIBS)
AC_SUBST(GTHUMB_CFLAGS)

AC_C_BIGENDIAN
AC_PROG_CPP
AC_PROG_CXX

#
# Checks for libjpeg
#
AC_MSG_CHECKING(JPEG Support)
AC_MSG_RESULT()

AC_CHECK_LIB(jpeg, jpeg_destroy_decompress,
	     [AC_CHECK_HEADER(jpeglib.h,,[AC_MSG_ERROR([*** JPEG headers not found ***])])],
	     [AC_MSG_ERROR([*** JPEG library not found ***])])

AC_CHECK_LIB(jpeg, jpeg_simple_progression,
	     [AC_DEFINE(HAVE_PROGRESSIVE_JPEG, 1, [Define to 1 if libjpeg supports progressive JPEG.])],
	     [AC_MSG_WARN(JPEG library does not support progressive saving.)])

AC_DEFINE(HAVE_LIBJPEG, 1, [Define to 1 if libjpeg support is included])

JPEG_LIBS='-ljpeg -lm -lz'
AC_SUBST(JPEG_LIBS)


#
# Checks for libtiff
#
AC_ARG_ENABLE([tiff],
	      [AC_HELP_STRING([--disable-tiff],[disable support for tiff])],,
	      [enable_tiff=yes])

HAVE_TIFF=no
if test x$enable_tiff = xyes ; then
   AC_MSG_CHECKING(TIFF Support)
   AC_MSG_RESULT()
   AC_CHECK_LIB(tiff, TIFFWriteScanline,
		[AC_CHECK_HEADER(tiffio.h,
				 AC_DEFINE(HAVE_LIBTIFF, 1, [Define to 1 if libtiff support is included])
				 TIFF_LIBS='-ltiff -lm -lz'
				 HAVE_TIFF=yes
				 ,[AC_MSG_WARN([*** TIFF headers not found ***])])],
		[AC_MSG_WARN([*** TIFF library not found ***])])
   AC_SUBST(TIFF_LIBS)
fi


#
# Checks for Xtest
#
have_xtest=false
XTEST_LIBS=""
AC_CHECK_LIB(Xtst, XTestFakeKeyEvent,
    have_xtest=true,:,-lX11 -lXtst $GTHUMB_LIBS)
if $have_xtest ; then
   XTEST_LIBS="-lX11 -lXtst"
   AC_DEFINE(HAVE_XTEST, 1, [Have XTest])
fi
AC_SUBST(XTEST_LIBS)


#
# Checks for libopenraw
#
AC_ARG_ENABLE([libopenraw],
	      [AC_HELP_STRING([--disable-libopenraw],[disable support for libopenraw])],,
	      [enable_libopenraw=yes])
HAVE_LIBOPENRAW=no
if test x$enable_libopenraw = xyes ; then
   PKG_CHECK_MODULES(LIBOPENRAW, libopenraw-gnome-1.0 >= $LIBOPENRAW_REQUIRED,
		     [AC_DEFINE(HAVE_LIBOPENRAW, 1, [Define to 1 to enable libopenraw support])
		      HAVE_LIBOPENRAW=yes],
		     [HAVE_LIBOPENRAW=no])
fi

#
# Checks for GDK X11 support; may not be present on MAC OS / Quartz systems
#
HAVE_GDKX=no
PKG_CHECK_MODULES(GDKX, gdk-x11-2.0,
		  [AC_DEFINE(HAVE_GDKX, 1, [Define to 1 if X11 support is included])
		   HAVE_GDKX=yes],
		  [AC_MSG_WARN(Disabling GDK/X11-dependent features and Xrender.)])


#
# check for gstreamer
#
AC_ARG_ENABLE([gstreamer],
              [AC_HELP_STRING([--disable-gstreamer], [Disable gstreamer metadata extraction])],,
              [enable_gstreamer=yes])
HAVE_GSTREAMER=no
if test "x$enable_gstreamer" = "xyes"; then
   PKG_CHECK_MODULES(GSTREAMER, gstreamer-0.10 >= $GSTREAMER_REQUIRED,
                     [AC_DEFINE(HAVE_GSTREAMER, 1, [Define to 1 to enable gstreamer support])
                      HAVE_GSTREAMER=yes],
                     [HAVE_GSTREAMER=no])
fi


#
# Checks for Xft/XRender
#
AC_ARG_ENABLE([render],
	      [AC_HELP_STRING([--disable-render],[disable support for Xrender])],,
	      [enable_render=yes])

HAVE_RENDER=no
if (test x$enable_render = xyes) && (test $HAVE_GDKX = yes); then
   AC_MSG_CHECKING(Xrender Support)
   AC_MSG_RESULT()
   AC_CHECK_LIB(Xrender, XRenderFindFormat,
                AC_DEFINE(HAVE_RENDER, 1, [Define to 1 if Xft/XRender support is included])
                RENDER_LIBS='-lXrender -lXext'
                HAVE_RENDER=yes
                ,,[-lXext $GTHUMB_LIBS])
   AC_SUBST(RENDER_LIBS)
fi

#
# Checks for Mac OS X menubar integration
#
AC_ARG_ENABLE([macos-menu],
              [AC_HELP_STRING([--disable-macos-menu],[disable support for Mac OS X menubar integration])],,
              [enable_macosmenu=yes])

HAVE_MACOSMENU=no
if test "x$enable_macosmenu" = "xyes"; then
   PKG_CHECK_MODULES(IGE_MAC_INTEGRATION, ige-mac-integration,
                     [AC_DEFINE(USE_MACOSMENU, 1, [Build with Mac OS X menubar integration])
                      HAVE_MACOSMENU=yes],
                     [HAVE_MACOSMENU=no])
fi

AM_CONDITIONAL(USE_IGE_MAC_INTEGRATION, test "x$HAVE_IGE-MAC-INTEGRATION" = "xyes")
AC_SUBST(IGE_MAC_INTEGRATION_CFLAGS)
AC_SUBST(IGE_MAC_INTEGRATION_LIBS)

dnl ###############################################

IDL_MODULES="bonobo-activation-2.0 libbonobo-2.0 libbonoboui-2.0"
IDL_INCLUDES="`$PKG_CONFIG --variable=idldir $IDL_MODULES | $srcdir/add-include-prefix`"
AC_SUBST(IDL_INCLUDES)


dnl ###############################################

AC_PATH_PROG(GLIB_GENMARSHAL, glib-genmarshal)
AC_PATH_PROG(GLIB_MKENUMS, glib-mkenums)


dnl ###############################################

IT_PROG_INTLTOOL([0.35.0])
GETTEXT_PACKAGE=gthumb
AC_SUBST([GETTEXT_PACKAGE])
AC_DEFINE_UNQUOTED([GETTEXT_PACKAGE],["$GETTEXT_PACKAGE"],[Gettext package])
AM_GLIB_GNU_GETTEXT


if test "x${prefix}" = "xNONE"; then
  AC_DEFINE_UNQUOTED(LOCALEDIR, "${ac_default_prefix}/${DATADIRNAME}/locale", [Locale directory])
else
  AC_DEFINE_UNQUOTED(LOCALEDIR, "${prefix}/${DATADIRNAME}/locale", [Locale directory])
fi

dnl ******************************

AC_ARG_ENABLE(deprecations,AC_HELP_STRING([--enable-deprecations],[warn about deprecated usages]))
if test "x$enable_deprecations" = "xyes"; then
        DISABLE_DEPRECATED="-DG_DISABLE_DEPRECATED \
        -DGDK_DISABLE_DEPRECATED \
        -DGDK_PIXBUF_DISABLE_DEPRECATED \
        -DGTK_DISABLE_DEPRECATED \
        -DGNOME_VFS_DISABLE_DEPRECATED \
        -DGNOME_DISABLE_DEPRECATED"
        AC_SUBST(DISABLE_DEPRECATED)
fi

dnl ******************************

WARN_CFLAGS="-Wall \ 
-Wpointer-arith -Wcast-align -Wtype-limits \
-Wclobbered -Wempty-body -Wignored-qualifiers"

for option in $WARN_CFLAGS; do
        SAVE_CFLAGS="$CFLAGS"
        CFLAGS="$CFLAGS $option"
        AC_MSG_CHECKING([whether gcc understands $option])
        AC_TRY_COMPILE([], [],
                       has_option=yes,
                       has_option=no,)
        if test x$has_option = xyes; then
                WARNINGS="$WARNINGS $option"
        fi
        AC_MSG_RESULT($has_option)
        CFLAGS="$SAVE_CFLAGS"
        unset has_option
        unset SAVE_CFLAGS
done
unset option
AC_SUBST(WARNINGS)

dnl ******************************

AC_PATH_PROG(GCONFTOOL, gconftool-2, no)
if test x"$GCONFTOOL" = xno; then
	AC_MSG_ERROR([gconftool-2 executable not found in your path - should be
installed with GConf])
fi
AM_GCONF_SOURCE_2

dnl ******************************

AC_MSG_CHECKING([for some Win32 platform])
case "$host" in
  *-*-cygwin*|*-*-mingw*)
    platform_win32=yes
    ;;
  *)
    platform_win32=no
    ;;
esac
AC_MSG_RESULT([$platform_win32])
AM_CONDITIONAL(PLATFORM_WIN32, test "$platform_win32" = "yes")

AC_MSG_CHECKING([for native Win32])
case "$host" in
  *-*-mingw*)
    os_win32=yes
    ;;
  *)
    os_win32=no
    ;;
esac
AC_MSG_RESULT([$os_win32])
AM_CONDITIONAL(OS_WIN32, test "$os_win32" = "yes")

dnl ******************************

if test "$platform_win32" = "yes" ; then
	MODULE_LIBTOOL_FLAGS='-module -avoid-version -no-undefined -Wl,$(top_builddir)/src/.libs/gthumb.exe.a'
else
	MODULE_LIBTOOL_FLAGS='-module -avoid-version'
fi
AC_SUBST(MODULE_LIBTOOL_FLAGS)

AC_OUTPUT([
Makefile
po/Makefile.in
libgthumb/Makefile
libgthumb/cursors/Makefile
libgthumb/icons/Makefile
libgthumb/jpegutils/Makefile
src/Makefile
src/icons/Makefile
doc/Makefile
data/Makefile
data/albumthemes/Makefile
data/albumthemes/BestFit/Makefile
data/albumthemes/Classic/Makefile
data/albumthemes/ClassicClips/Makefile
data/albumthemes/Flicker/Makefile
data/albumthemes/NeatRound/Makefile
data/albumthemes/Wiki/Makefile
data/glade/Makefile
data/icons/Makefile
data/icons/16x16/Makefile
data/icons/16x16/apps/Makefile
data/icons/22x22/Makefile
data/icons/22x22/apps/Makefile
data/icons/32x32/Makefile
data/icons/32x32/apps/Makefile
data/icons/48x48/Makefile
data/icons/48x48/apps/Makefile
data/icons/scalable/Makefile
data/icons/scalable/apps/Makefile
])

echo "

Configuration:

	Source code location:     ${srcdir}
	Compiler:                 ${CC}
	Have gdk-x11:		  ${HAVE_GDKX}
	Have XRender:             ${HAVE_RENDER}
	Have XTest:               ${have_xtest}
	Have libtiff:             ${HAVE_TIFF}
	Have libopenraw:          ${HAVE_LIBOPENRAW}
	Have gstreamer:           ${HAVE_GSTREAMER}
	Use Mac OS X menu:        ${HAVE_MACOSMENU}

"